path: root/PKGBUILD

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Aqua-sama <aqua@iserlohn-fortress.net>

# # I maintain this because:
# Arch version patch script does not apply consistently
# Arch version lacks graysky gcc patch with bdver2 fix
# Arch version lacks ath9k regdom and raid6 algo patches
# Arch version lacks ck patches
# Arch version is 300 Hz
# Arch version does not disable eee
# Arch version enables insecure filesystems and staging drivers
# Arch version enables ISDN and Infiniband
# Arch version enables VMware and HyperV
# Arch version builds documentation

pkgbase=linux-ck
_supver=5
_majver=4
_minver=6
_gccpatchver='20190822'
_ckpatchversion=ck1
  if [ "$_minver" == "0" ]; then
    pkgver=${_supver}.${_majver}
  else
    pkgver=${_supver}.${_majver}.${_minver}
  fi
pkgrel=3
pkgdesc='Linux-ck'
url='https://kernel.org'
#url='http://ck.kolivas.org/patches/'
arch=(x86_64)
license=(GPL2)
makedepends=(
  bc kmod libelf
)
conflicts=('linux-libre-ck')
options=('!strip')
_srcname=linux-${pkgver}
source=(
  https://www.kernel.org/pub/linux/kernel/v${_supver}.x/${_srcname}.tar.{xz,sign}
  0001-ZEN-Add-sysctl-and-CONFIG-to-disallow-unprivileged-CLONE_NEWUSER.patch
  0002-lib-devres-add-a-helper-function-for-ioremap_uc.patch
  0003-mfd-intel-lpss-Use-devm_ioremap_uc-for-MMIO.patch
  0004-PCI-pciehp-Do-not-disable-interrupt-twice-on-suspend.patch
  0005-PCI-pciehp-Prevent-deadlock-on-disconnect.patch
  0006-ACPI-PM-s2idle-Rework-ACPI-events-synchronization.patch
  0007-x86-MCE-AMD-Do-not-use-rdmsr_safe_on_cpu-in-smca_configure.patch
  0008-x86-MCE-AMD-Allow-Reserved-types-to-be-overwritten-in-smca_banks.patch
  0009-x86-mce-Fix-possibly-incorrect-severity-calculation-on-AMD.patch
  0010-Revert-iwlwifi-assign-directly-to-iwl_trans-cfg-in-QuZ-detection.patch
  0011-iwlwifi-pcie-move-power-gating-workaround-earlier-in-the-flow.patch
  0012-x86-intel-Disable-HPET-on-Intel-Coffee-Lake-H-platforms.patch
  0013-x86-intel-Disable-HPET-on-Intel-Ice-Lake-platforms.patch
  0014-drm-i915-save-AUD_FREQ_CNTRL-state-at-audio-domain-suspend.patch
  0015-drm-i915-Fix-audio-power-up-sequence-for-gen10-display.patch
  0016-drm-i915-extend-audio-CDCLK-2BCLK-constraint-to-more-platforms.patch
  0017-ASoC-SOF-enable-sync_write-in-hdac_bus.patch
  0018-xhci-pci-Allow-host-runtime-PM-as-default-also-for-Intel-Ice-Lake-xHCI.patch
  0019-iwlwifi-pcie-restore-support-for-Killer-Qu-C0-NICs.patch
  linux-ck-patch-${_supver}.${_majver}-${_ckpatchversion}.xz::http://ck.kolivas.org/patches/${_supver}.0/${_supver}.${_majver}/${_supver}.${_majver}-${_ckpatchversion}/patch-${_supver}.${_majver}-${_ckpatchversion}.xz
  graysky_bdver2-hotfix.patch
  kernel_gcc_patch-${_gccpatchver}.tar.gz::https://github.com/graysky2/kernel_gcc_patch/archive/${_gccpatchver}.tar.gz
  ath9k-regdom-hack.patch
  raid6-default-algo.patch
  config         # the main kernel config file
)
validpgpkeys=(
  'ABAF11C65A2970B130ABE3C479BE3E4300411886'  # Linus Torvalds
  '647F28654894E3BD457199BE38DBBDC86092693E'  # Greg Kroah-Hartman
)
# https://www.kernel.org/pub/linux/kernel/v5.x/sha256sums.asc
sha256sums=('fda561bcdea397ddd59656319c53871002938b19b554f30efed90affa30989c8'
            'SKIP'
            '89db33f4292df124d7048329b113d57d928059ecf94abc7840983aeecaf747bd'
            'f04a451706241e85f49d85c7d9bd892495b2e9d4eb0a353de333e375ed3b3d14'
            '15dcdeec72aa042ceb272326225d22dd5f934cd7fa0746924eced3eb4f77703e'
            '2d3afe3896644896510cd7a4694a94692a7ca8173006ce8eaa37c87abf2830c8'
            '4b3c1cab1ec9258e7632cbdf9bb289186b66d702ada3e5672275297b76f3b226'
            'bd333d79a0f0a21f9da070e27f55786a0355036021b72e91757517daf6412a6d'
            'a2e1db6e523c7dcec894279650b9bc289df0eb938465aea301e1abd929916da6'
            'cd402b412aee8e6406859ff85da12b796b89f35ef96fa3931fcda9105e314026'
            '77f208ab5c1d6163f4f914dfe8087a3cd6a482df60fcfb9ec14201f8d24fc16b'
            '582999d7189c165bf2d6be2edde2aad4091f787ef16ca1d8bc3736c6871fe2f5'
            '540a85b2ab3ef087fe3a9db40d827f37756df8eeebb3022698f97e5c96491dcb'
            'ee6fabf26cb8f79e59756cfca2f5ba687cf219079b2c67e808ff8bc58074b02e'
            '1bcec07561c785e22ca43a140b07b586bc7717ea3c08e7549ec7a3bdfa39b7e2'
            'e2084feabc3abeed37579ff515c367014356a652b85794b1612fea4daabe85d3'
            '988ffbb96d85564a9d96145e5973339a8f78ae95d919efb2ee7bb50f7a8e8fc9'
            '5257159e20a5fcb102a3b3ee6de33882a9e132e7f1d4345b8730effdd0240bb6'
            '9e79411a264e4d469a254f4152cd3d90f77db7027e2fd967bd666c1deed608a6'
            'a99491d413f25af14c7b2c6f0daeb45670191772e3ae96424cd11eff268a4715'
            '2516be40fe063f7a448c69f170d628dbf549c3e084c2c7eb6910fd4782a6e73f'
            'f445eea4d0ec2015a25f1ad625c848f4f2252099795966fa4105e0aa29674c5c'
            'c5405139aa0a90a6f68f6a13e066a2bd0600c970f9f525cd3aa114b044a7f73b'
            '8c11086809864b5cef7d079f930bd40da8d0869c091965fa62e95de9a0fe13b5'
            'e7ebf050c22bcec0028c0b3c79fd6d3913b0370ecc6a23dfe78ce475630cf503'
            '0f81d6e4158b7beeb0eb514f1b9401f7e23699cb0f7b0d513e25dae1815daaeb'
            '8f5bcac15a23686d02d3c9324b03a51a8ac3caebd1e731ab6df3f007aea3b4f1')

#export KBUILD_BUILD_HOST=arc4linux
export KBUILD_BUILD_USER=$pkgbase
export KBUILD_BUILD_TIMESTAMP="$(date -Ru${SOURCE_DATE_EPOCH:+d @$SOURCE_DATE_EPOCH})"

prepare() {
  cd $_srcname

  # add upstream patch
#  if [ "$_minver" != "0" ]; then
#    msg2 "Applying upstream patch"
#    patch -Np1 < ../patch-${_supver}.${_majver}-${pkgver}
#  fi


  # Hotfixes
  msg2 "Applying hotfixes"
  patch -p1 -i ../0001-ZEN-Add-sysctl-and-CONFIG-to-disallow-unprivileged-CLONE_NEWUSER.patch
  patch -p1 -i ../0002-lib-devres-add-a-helper-function-for-ioremap_uc.patch
  patch -p1 -i ../0003-mfd-intel-lpss-Use-devm_ioremap_uc-for-MMIO.patch
  patch -p1 -i ../0004-PCI-pciehp-Do-not-disable-interrupt-twice-on-suspend.patch
  patch -p1 -i ../0005-PCI-pciehp-Prevent-deadlock-on-disconnect.patch
  patch -p1 -i ../0006-ACPI-PM-s2idle-Rework-ACPI-events-synchronization.patch
  patch -p1 -i ../0007-x86-MCE-AMD-Do-not-use-rdmsr_safe_on_cpu-in-smca_configure.patch
  patch -p1 -i ../0008-x86-MCE-AMD-Allow-Reserved-types-to-be-overwritten-in-smca_banks.patch
  patch -p1 -i ../0009-x86-mce-Fix-possibly-incorrect-severity-calculation-on-AMD.patch
  patch -p1 -i ../0010-Revert-iwlwifi-assign-directly-to-iwl_trans-cfg-in-QuZ-detection.patch
  patch -p1 -i ../0011-iwlwifi-pcie-move-power-gating-workaround-earlier-in-the-flow.patch
  patch -p1 -i ../0012-x86-intel-Disable-HPET-on-Intel-Coffee-Lake-H-platforms.patch
  patch -p1 -i ../0013-x86-intel-Disable-HPET-on-Intel-Ice-Lake-platforms.patch
  patch -p1 -i ../0014-drm-i915-save-AUD_FREQ_CNTRL-state-at-audio-domain-suspend.patch
  patch -p1 -i ../0015-drm-i915-Fix-audio-power-up-sequence-for-gen10-display.patch
  patch -p1 -i ../0016-drm-i915-extend-audio-CDCLK-2BCLK-constraint-to-more-platforms.patch
  patch -p1 -i ../0017-ASoC-SOF-enable-sync_write-in-hdac_bus.patch
  patch -p1 -i ../0018-xhci-pci-Allow-host-runtime-PM-as-default-also-for-Intel-Ice-Lake-xHCI.patch
  patch -p1 -i ../0019-iwlwifi-pcie-restore-support-for-Killer-Qu-C0-NICs.patch

  # fix naming schema in EXTRAVERSION of ck patch set
  sed -i -re "s/^(.EXTRAVERSION).*$/\1 = /" "../linux-ck-patch-${_supver}.${_majver}-${_ckpatchversion}"

  # ck patch
  msg2 "Applying ck patch"
  patch -F 3 -Np1 -i ../linux-ck-patch-${_supver}.${_majver}-${_ckpatchversion}


  # graysky gcc hotfixes
  msg2 "Applying graysky gcc patch hotfixes"
  patch -p1 -i ../graysky_bdver2-hotfix.patch "$srcdir/kernel_gcc_patch-${_gccpatchver}/enable_additional_cpu_optimizations_for_gcc_v9.1+_kernel_v4.13+.patch"

  # graysky gcc patch
  msg2 "Applying graysky cpu patch"
  patch -p1 -i ../kernel_gcc_patch-${_gccpatchver}/enable_additional_cpu_optimizations_for_gcc_v9.1+_kernel_v4.13+.patch


  # Ignore ath9k eeprom patch
  msg2 "Applying ath9k patch"
  patch -p1 -i ../ath9k-regdom-hack.patch

  # Set default raid6 algo patch
  msg2 " Applying raid6 patch"
  patch -p1 -i ../raid6-default-algo.patch


  msg2 "Setting version..."
  scripts/setlocalversion --save-scmversion
  echo "-$pkgrel" > localversion.10-pkgrel
  echo "${pkgbase#linux}" > localversion.20-pkgname


  msg2 "Setting config..."
  # we are in src/linux-x.yy.zz, looking for a config next to the pkgbuild
  if [ -f ${SRCDEST}/config.ck.previous ]; then
    cp ${SRCDEST}/config.ck.previous .config
  else
    cp ../config .config
  fi

  make olddefconfig

  make menuconfig

  # Remove sublevel when no sublevel exists
  if [ "$_minver" == "0" ]; then
    sed -i '/SUBLEVEL = 0/d' Makefile
  fi

  make -s kernelrelease > version

  # workaround for make -s kernelrelease not applying
  # localversion to version when changed using menuconfig
  grep -Po '(?<=CONFIG_LOCALVERSION=").*(?=")' .config > ../localversion
  echo "$pkgver" > ../version.temp
  cat "localversion.10-pkgrel" >> ../version.temp
  cat "localversion.20-pkgname" >> ../version.temp
  cat ../localversion >> ../version.temp
  cat ../version.temp | tr -d "\n" > version

  # back up the config
  msg2 "Backing up config..."
  cp .config ${SRCDEST}/config.ck.previous

  msg2 "Prepared %s version %s" "$pkgbase" "$(<version)"
}

build() {
  cd $_srcname
  make bzImage modules
}

_package() {
  pkgdesc="The $pkgdesc kernel and modules"
  depends=(coreutils kmod initramfs)
  optdepends=('crda: to set the correct wireless channels of your country'
              'linux-firmware: firmware images needed for some devices')

  cd $_srcname
  local kernver="$(<version)"
  local modulesdir="$pkgdir/usr/lib/modules/$kernver"

  msg2 "Installing boot image..."
  # systemd expects to find the kernel here to allow hibernation
  # https://github.com/systemd/systemd/commit/edda44605f06a41fb86b7ab8128dcf99161d2344
  install -Dm644 "$(make -s image_name)" "$modulesdir/vmlinuz"

  # Used by mkinitcpio to name the kernel
  echo "$pkgbase" | install -Dm644 /dev/stdin "$modulesdir/pkgbase"

  msg2 "Installing modules..."
  make INSTALL_MOD_PATH="$pkgdir/usr" modules_install

  # remove build and source links
  rm "$modulesdir"/{source,build}

  msg2 "Fixing permissions..."
  chmod -Rc u=rwX,go=rX "$pkgdir"
}

_package-headers() {
  pkgdesc="Header files and scripts for building modules for $pkgdesc kernel"

  cd $_srcname
  local builddir="$pkgdir/usr/lib/modules/$(<version)/build"

  msg2 "Installing build files..."
  install -Dt "$builddir" -m644 .config Makefile Module.symvers System.map \
    localversion.* version vmlinux
  install -Dt "$builddir/kernel" -m644 kernel/Makefile
  install -Dt "$builddir/arch/x86" -m644 arch/x86/Makefile
  cp -t "$builddir" -a scripts

  # add objtool for external module building and enabled VALIDATION_STACK option
  if [[ -e tools/objtool/objtool ]]; then
    install -Dt "$builddir/tools/objtool" tools/objtool/objtool
  fi

  # add xfs and shmem for aufs building
  mkdir -p "$builddir"/{fs/xfs,mm}

  msg2 "Installing headers..."
  cp -t "$builddir" -a include
  cp -t "$builddir/arch/x86" -a arch/x86/include
  install -Dt "$builddir/arch/x86/kernel" -m644 arch/x86/kernel/asm-offsets.s

  install -Dt "$builddir/drivers/md" -m644 drivers/md/*.h
  install -Dt "$builddir/net/mac80211" -m644 net/mac80211/*.h

  # http://bugs.archlinux.org/task/13146
  install -Dt "$builddir/drivers/media/i2c" -m644 drivers/media/i2c/msp3400-driver.h

  # http://bugs.archlinux.org/task/20402
  install -Dt "$builddir/drivers/media/usb/dvb-usb" -m644 drivers/media/usb/dvb-usb/*.h
  install -Dt "$builddir/drivers/media/dvb-frontends" -m644 drivers/media/dvb-frontends/*.h
  install -Dt "$builddir/drivers/media/tuners" -m644 drivers/media/tuners/*.h

  msg2 "Installing KConfig files..."
  find . -name 'Kconfig*' -exec install -Dm644 {} "$builddir/{}" \;

  msg2 "Removing unneeded architectures..."
  local arch
  for arch in "$builddir"/arch/*/; do
    [[ $arch = */x86/ ]] && continue
    echo "Removing $(basename "$arch")"
    rm -r "$arch"
  done

  msg2 "Removing documentation..."
  rm -r "$builddir/Documentation"

  msg2 "Removing broken symlinks..."
  find -L "$builddir" -type l -printf 'Removing %P\n' -delete

  msg2 "Removing loose objects..."
  find "$builddir" -type f -name '*.o' -printf 'Removing %P\n' -delete

  msg2 "Stripping build tools..."
  local file
  while read -rd '' file; do
    case "$(file -bi "$file")" in
      application/x-sharedlib\;*)      # Libraries (.so)
        strip -v $STRIP_SHARED "$file" ;;
      application/x-archive\;*)        # Libraries (.a)
        strip -v $STRIP_STATIC "$file" ;;
      application/x-executable\;*)     # Binaries
        strip -v $STRIP_BINARIES "$file" ;;
      application/x-pie-executable\;*) # Relocatable binaries
        strip -v $STRIP_SHARED "$file" ;;
    esac
  done < <(find "$builddir" -type f -perm -u+x ! -name vmlinux -print0)

  msg2 "Adding symlink..."
  mkdir -p "$pkgdir/usr/src"
  ln -sr "$builddir" "$pkgdir/usr/src/$pkgbase"

  msg2 "Fixing permissions..."
  chmod -Rc u=rwX,go=rX "$pkgdir"
}

pkgname=("$pkgbase" "$pkgbase-headers")
for _p in "${pkgname[@]}"; do
  eval "package_$_p() {
    $(declare -f "_package${_p#$pkgbase}")
    _package${_p#$pkgbase}
  }"
done