1 files changed, 51 insertions, 0 deletions
diff --git a/linux/makepkg/PKGBUILD b/linux/makepkg/PKGBUILD
new file mode 100644
index 0000000..0d9fc88
--- /dev/null
+++ b/linux/makepkg/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: xiannox <xiannox@iserlohn-fortress.net>
+
+pkgname=smolbote-git
+pkgver=0.1.0
+pkgrel=1
+pkgdesc='Yet another Qt browser'
+url="https://neueland.iserlohn-fortress.net/smolbote"
+
+arch=('x86_64')
+license=('GPL3')
+
+depends=('qt5-base' 'qt5-webengine')
+makedepends=('git' 'qt5-tools' 'qbs')
+
+source=("git+git://neueland.iserlohn-fortress.net/smolbote.git")
+sha512sums=('SKIP')
+
+# qmake location for your Qt version
+# Useful if you have another Qt version installed in a specific location
+_qmake='/usr/bin/qmake-qt5'
+# install root, ex: '/usr' or '/usr/local'
+# Should this install in /usr/bin, or in /usr/local/bin, or perhaps in /somewhere/else/bin?
+_iroot='/usr/local'
+
+pkgver() {
+    cd smolbote
+    echo "$(git describe --long --tags | tr - .)"
+}
+
+prepare() {
+    # Prepare the qbs modules
+    rm -rf config
+    mkdir config
+    qbs-setup-toolchains --settings-dir config --detect
+    qbs-setup-qt --settings-dir config ${_qmake} qt
+
+    # Clear out the build folder
+    rm -rf build
+    mkdir build
+}
+
+build() {
+    cd smolbote
+    qbs build --settings-dir ../config -d ../build  profile:qt release
+}
+
+package() {
+    cd smolbote
+    qbs install --settings-dir ../config -d ../build --install-root "${pkgdir}${_iroot}" profile:qt release
+}
+