1 files changed, 42 insertions, 0 deletions
diff --git a/plugins/smolblok_hostlist/meson.build b/plugins/smolblok_hostlist/meson.build
new file mode 100644
index 0000000..a3e64a7
--- /dev/null
+++ b/plugins/smolblok_hostlist/meson.build
@@ -0,0 +1,42 @@
+lib_hostlistfilter = static_library('hostlistfilter',
+  [ 'filterlist.cpp' ],
+  include_directories: smolbote_interfaces,
+  dependencies: [dep_qt5]
+)
+
+dep_hostlistfilter = declare_dependency(
+  include_directories: [ '.', smolbote_interfaces ],
+  link_with: lib_hostlistfilter
+)
+
+# plugin
+plugin = shared_library('smolblokHostlistPlugin',
+  [ 'plugin/plugin.cpp',
+    mod_qt5.preprocess(include_directories: smolbote_interfaces, moc_headers: 'plugin/plugin.h', dependencies: dep_qt5) ],
+  include_directories: smolbote_interfaces,
+  dependencies: [ dep_hostlistfilter, dep_qt5 ],
+  install: true,
+  install_dir: get_option('libdir')/'smolbote/plugins'
+)
+
+# tests
+test('rule parsing', executable('rule', 
+  sources: 'test/rule.cpp',
+  dependencies: [dep_qt5, dep_catch, dep_hostlistfilter]))
+
+test('filterlist', executable('filterlist',
+  sources: 'test/filterlist.cpp',
+  dependencies: [dep_qt5, dep_catch, dep_hostlistfilter]),
+  env: 'HOSTLIST_TXT='+meson.current_source_dir()/'test/hostlist.txt'
+)
+
+# fuzzer
+if meson.get_compiler('cpp').has_multi_arguments('-g', '-fsanitize=fuzzer')
+executable('hostlist-fuzzer',
+  sources: 'filterlist.cpp',
+  include_directories: smolbote_interfaces,
+  dependencies: dep_qt5,
+  cpp_args: [ '-g', '-fsanitize=fuzzer', '-DFUZZER' ],
+  link_args: [ '-fsanitize=fuzzer' ]
+)
+endif