cmake_minimum_required(VERSION 3.1.0)
project(smolbote)

include(FeatureSummary)

# Options
option(MercurialRepo "Get version information from .hg" ON)
option(CompilerWarnings "Compiler warnings" ON)
option(QtDeprecatedWarnings "Qt deprecated warnings" ON)
option(UseLibCpp "Use libc++ over stdlibc++ (requires clang)" OFF)
option(Tests "Enable/disable some basic autotests" ON)

# Libraries
find_package(Qt5 COMPONENTS Core Widgets Concurrent REQUIRED)
find_package(Qt5 5.11 COMPONENTS WebEngineWidgets REQUIRED)
find_package(Boost COMPONENTS program_options REQUIRED)

# Global C++ settings
set(CMAKE_CXX_STANDARD 17)

if(CompilerWarnings)
    if(CMAKE_COMPILER_IS_GNUCC)
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
    endif()
    if(MSVC)
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
    endif()
endif(CompilerWarnings)

if(QtDeprecatedWarnings)
    add_definitions(-DQT_DEPRECATED_WARNINGS -DQT_DISABLE_DEPRECATED_BEFORE=0x050900)
endif(QtDeprecatedWarnings)

# link to libc++
if (UseLibCpp)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -stdlib=libc++")
endif (UseLibCpp)

# detect version and commit from mercurial
if (MercurialRepo AND EXISTS "${PROJECT_SOURCE_DIR}/.hg")
    execute_process(COMMAND hg log -r '.' --template={latesttag} WORKING_DIRECTORY ${PROJECT_SOURCE_DIR} OUTPUT_VARIABLE VcsVersion  OUTPUT_STRIP_TRAILING_WHITESPACE)
    execute_process(COMMAND hg identify --id                     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR} OUTPUT_VARIABLE VcsCommit   OUTPUT_STRIP_TRAILING_WHITESPACE)
    execute_process(COMMAND hg identify --num                    WORKING_DIRECTORY ${PROJECT_SOURCE_DIR} OUTPUT_VARIABLE VcsRevision OUTPUT_STRIP_TRAILING_WHITESPACE)
    execute_process(COMMAND hg identify --branch                 WORKING_DIRECTORY ${PROJECT_SOURCE_DIR} OUTPUT_VARIABLE VcsBranch   OUTPUT_STRIP_TRAILING_WHITESPACE)
endif()

# configure a header file to pass version information
# if repo is missing or option is turned off, version.h.in can be configured
# with static values
configure_file("${PROJECT_SOURCE_DIR}/src/version.h.in" "${PROJECT_BINARY_DIR}/src/version.h")

add_subdirectory(lib/bookmarks)
add_subdirectory(lib/downloads)
add_subdirectory(lib/configuration)

add_subdirectory(plugins/ProfileEditor)

# browser source code
add_subdirectory(src)

# configuration program
add_subdirectory(config)

if (Tests)
    enable_testing()
    find_package(Qt5 COMPONENTS Test REQUIRED)
    add_subdirectory(test)
endif()

feature_summary(WHAT ALL)