# Maintainer: Aqua-sama <aqua at iserlohn-fortress dot net>

## not-use flags
# Enable plugin signing:
_signPlugins=0
# install prefix
_prefix='/usr/local'

pkgname=smolbote-git
pkgdesc='Yet another no-frills browser'
pkgver=0
pkgrel=1

url="https://neueland.iserlohn-fortress.net/cgit/smolbote"

arch=('x86_64' 'aarch64')
license=('GPL3')

depends=('qt5-svg' 'qt5-webengine>=5.11.0' 'spdlog')
makedepends=('git' 'cmake' 'python-kconfiglib' 'openssl' 'qt5-tools' 'scdoc' 'catch2')
optdepends=('firejail: launch a sandboxed instance')

# use git+file:///path/to/your/repo#branch=devel to build from a local repo
source=("git+git://neueland.iserlohn-fortress.net/cgit/smolbote#branch=devel"
        "https://github.com/itay-grudev/SingleApplication/archive/v3.1.5.tar.gz"
        "https://neueland.iserlohn-fortress.net/cgit/rcc/snapshot/rcc-0.1.2.tar.xz"
        "https://github.com/tabler/tabler-icons/archive/v1.34.0.tar.gz")

sha256sums=('SKIP'
    '09b1e088dae8cf69187262554819b77f4ca7b65576b3f39c5b6885823e8a2dbb'
    '5ee18b94401b720e6e65d8e0e38dd6ea23cab7ae4727742be313530969a69d50'
    'bc74e5bd28531445f2e50df44f3688b1116397a25a0086e6944ab52260b70ffd'
)

prepare() {
    mkdir "$srcdir/smolbote-devel/third-party"
    ln -s "$srcdir/SingleApplication-3.1.5" "$srcdir/smolbote-devel/third-party/"
    ln -s "$srcdir/rcc-0.1.2" "$srcdir/smolbote-devel/third-party/"
    ln -s "$srcdir/tabler-icons-1.34.0" "$srcdir/smolbote-devel/third-party/"
    ln -s "$srcdir/smolbote-devel/linux/.config" "$srcdir/smolbote-devel/"
}

pkgver() {
    cd "$srcdir/smolbote-devel"
    # Without version tag
    echo r$(git rev-list --count HEAD)-$(git rev-parse --short HEAD) | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cmake -B build -S "smolbote-devel" -DVCS_TAG=OFF -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=$_prefix
    make -C build

}

package() {
    make DESTDIR="$pkgdir" -C build install
}