# Maintainer: Aqua-sama <aqua@iserlohn-fortress.net>


## not-use flags Options
# Enable plugin signing:
_signPlugins=0
# Enable breakpad integraton:
_enableBreakpad=0
# test
_test=1


pkgname=smolbote-git
pkgdesc='Yet another no-frills browser'
pkgver=0
pkgrel=1

url="https://neueland.iserlohn-fortress.net/gitea/smolbote"
install="smolbote.install"

arch=('x86_64' 'aarch64')
license=('GPL3')

depends=('qt5-webengine>=5.11.0' 'spdlog')
if [ $_enableBreakpad == "1" ]; then
  makedepends=('git' 'meson' 'python-kconfiglib' 'openssl' 'qt5-tools' 'scdoc' 'breakpad-git')
else
  makedepends=('git' 'meson' 'python-kconfiglib' 'openssl' 'qt5-tools' 'scdoc')
fi
optdepends=('firejail: launch a sandboxed instance')

# use git+file:///path/to/your/repo to build from a local repo
source=("git+https://library.iserlohn-fortress.net/aqua/smolbote.git"
        "git+https://github.com/itay-grudev/SingleApplication.git"
        "git+https://github.com/Taywee/args")

sha512sums=('SKIP'
            'SKIP'
            'SKIP')

#validgpgkeys=(BB1C090188E3E32B375C13FD095DE26BC16D2E98) # Aqua-sama <aqua@iserlohn-fortress.net>

prepare() {
    cd $srcdir/smolbote

    git submodule init
    git config submodule.3rd-party/SingleApplication/SingleApplication.git.url $srcdir/SingleApplication
    git submodule update 3rd-party/SingleApplication/SingleApplication.git
    git config submodule.3rd-party/args/args.git.url $srcdir/args
    git submodule update 3rd-party/args/args.git
}

pkgver() {
    cd smolbote
    # Without version tag
    echo r$(git rev-list --count HEAD)-$(git rev-parse --short HEAD) | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    mkdir -p $srcdir/build
    cd $srcdir/smolbote
    KCONFIG_CONFIG=linux/.config alldefconfig

    # For a list of configureable options, check smolbote/meson_options.txt, or
    # run `meson configure` in $srcdir/build

    # --wrap-mode=nodownload - disable meson from downloading dependency wraps. This will cause it to fail if makedepends are not found by pkg-config or cmake.
    # --wrap-mode=nofallback - disable downloads as a fallback too. Implies --wrap-mode=nodownload
    # --buildtype=plain - meson won't add any flags to the command line
    # --prefix=... - install prefix
    # --auto-features=disabled - features should be explicitly enabled
    # b_pie: Build executables as position independent
    # b_lto: Use link time optimization
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4"
  export LDFLAGS="$LDFLAGS,-fuse-ld=gold"
    meson --buildtype=plain --wrap-mode=nodownload \
        --prefix=/usr/local --auto-features=disabled \
        -Db_pie=true \
        -Dmanpage=enabled \
        $srcdir/build

    if [ $_enableBreakpad == "1" ]; then
        msg2 "Enabling crashhandler"
        meson configure -Ddebug=true -Dcrashhandler=enabled
        KCONFIG_CONFIG=linux/.config setconfig USEBREAKPAD=y
    fi

    # Run menuconfig
    #KCONFIG_CONFIG=linux/.config menuconfig

    # Build
    ninja -C $srcdir/build "$MAKEFLAGS"
}

package() {
    # Install
    cd $srcdir/build
    DESTDIR="$pkgdir" ninja install

    if [ $_signPlugins == "1" ]; then
    msg "Signing plugins"
    for so in $pkgdir/usr/local/lib/smolbote/plugins/*.so; do
        msg2 "Signed $(basename $so)"
        openssl dgst -sha256 -sign $srcdir/build/privateKey.pem -out $so.sig $so
    done
    fi

    if [ $_enableBreakpad == "1" ]; then
        msg "Installing debug symbols"
        ninja -C $srcdir/build linux/poi.sym
        install -dm644 $pkgdir/usr/local/lib/smolbote/symbols/poi/$(head -n1 linux/poi.sym | awk '{ print $(NF-1) }') 
        install -m644 -t $pkgdir/usr/local/lib/smolbote/symbols/poi/$(head -n1 linux/poi.sym | awk '{ print $(NF-1) }') $srcdir/build/linux/poi.sym
    fi
}