# Maintainer: Aqua-sama <aqua@iserlohn-fortress.net>

pkgname=smolbote-git
pkgdesc='Yet another no-frills browser'

pkgver=r0
pkgrel=1
_tag=""
_describe=""
_commit=""
_branch=""

url="https://neueland.iserlohn-fortress.net/smolbote"

arch=('x86_64')
license=('GPL3')

depends=('qt5-webengine>=5.11.0' 'boost-libs>=1.66.0')
optdepends=('firejail: launch a sandboxed instance')
makedepends=('git' 'cmake' 'pkg-config' 'asciidoctor')

# this is the central repository
source=("git+https://neueland.iserlohn-fortress.net/gitea/aqua/smolbote.git"
        "git+https://github.com/itay-grudev/SingleApplication.git")

sha512sums=('SKIP'
            'SKIP')

#validgpgkeys=(# Aqua-sama <aqua@iserlohn-fortress.net>
#              BB1C090188E3E32B375C13FD095DE26BC16D2E98)

prepare() {
    cd smolbote

    git submodule init
    git config submodule.3rd-party/SingleApplication/SingleApplication.git.url $srcdir/SingleApplication
    git submodule update 3rd-party/SingleApplication/SingleApplication.git

    _tag="r$(git rev-list --count HEAD)"
    _describe="r$(git rev-list --count HEAD)-$(git rev-parse --short HEAD)"
    _commit=$(git rev-parse HEAD)
    _branch=$(git rev-parse --abbrev-ref HEAD)
}

pkgver() {
    cd smolbote
    echo $_describe | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    # generate makefile

    #  option                   default
    # -DQtDeprecatedWarnings    On
    # -DUseLibCpp               Off
    # -DTests                   Off
    # -DPlasma                  Off
    # -DBreakpad                Off     If you turn it on, add a breakpad
    #                                   dependancy to makedepends, or modify
    #                                   3rd-pary/breakpad/CMakeLists.txt
    #                                   accordingly.

    cmake   -DCMAKE_BUILD_TYPE=Release \
            -DCMAKE_INSTALL_PREFIX=$pkgdir/usr/local \
            -DVerTag=$_tag \
            -DVerDescribe=$_describe \
            -DVerCommit=$_commit \
            -DVerBranch=$_branch \
            $srcdir/smolbote

    # Build
    make
}

package() {
    # Install
    make install

    msg2 "Installing icon and .desktop"
    install -Dm644 $srcdir/smolbote/data/poi.svg $pkgdir/usr/share/icons/hicolor/scalable/apps/poi.svg
    install -Dm644 $srcdir/smolbote/linux/poi.desktop $pkgdir/usr/share/applications/poi.desktop

    msg2 "Installing firejail profile"
    install -Dm644 $srcdir/smolbote/data/poi.profile $pkgdir/usr/local/lib/smolbote/poi.profile

    msg2 "Installing manpage"
    asciidoctor --backend=manpage $srcdir/smolbote/doc/smolbote.7.asciidoc
    gzip $srcdir/smolbote/doc/smolbote.7
    install -Dm644 $srcdir/smolbote/doc/smolbote.7.gz $pkgdir/usr/local/man/man7/smolbote.7.gz
}