project('smolbote', 'cpp',
    version: 'master',
    default_options: ['cpp_std=c++17', 'strip=true', 'warning_level=3'],
    license: 'GPL3')

# Qt 5
qt5 = import('qt5')
dep_qt5 = dependency('qt5', modules: ['Core', 'Gui', 'Network', 'Widgets', 'WebEngineWidgets'])

# Boost
dep_boost = dependency('boost', modules: ['program_options'])

# Breakpad
dep_breakpad = dependency('breakpad-client', required : get_option('Breakpad'))

# Generate config header
include = include_directories('include')
conf = configuration_data()
conf.set_quoted('poi_Version', '1.0.0')
conf.set_quoted('poi_Describe', '1.0.0-stable')
conf.set_quoted('poi_Build', 'custom-1.0.0')

configure_file(configuration: conf, input: 'include/version.h.in', output: 'version.h')
genheader_inc = include_directories('.')

pymod = import('python')
python3 = pymod.find_installation('python3')

kconfiggen = custom_target('configheader',
    input: ['tools/config.py', 'src/Kconfig', 'linux/.config'],
    output: 'config.h',
    command: [python3, '@INPUT0@', '--kconfig=@INPUT1@', '--dotconfig=@INPUT2@', '--generate=@OUTPUT@'],
    build_by_default: true
)

lib_inc = include_directories('lib')
subdir('lib/about')
subdir('lib/addressbar')
subdir('lib/bookmarks')
subdir('lib/configuration')
subdir('lib/downloads')
subdir('lib/urlfilter')
subdir('lib/web')

thirdparty_inc = include_directories('3rd-party/SingleApplication/SingleApplication.git')
subdir('3rd-party/SingleApplication')

subdir('src')