# Find includes in corresponding build directories
set(CMAKE_INCLUDE_CURRENT_DIR ON)

# Instruct CMake to run moc automatically when needed.
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)

set(srclist
        # main
        main.cpp
        browser.cpp
        browser.h
        session.cpp
        session.h
        util.cpp
        util.h

        # resources (icons, etc)
        ${PROJECT_SOURCE_DIR}/data/resources.qrc

        # main window
        mainwindow/mainwindow.cpp
        mainwindow/mainwindow.h
        mainwindow/mainwindow.ui
        mainwindow/widgets/dockwidget.cpp
        mainwindow/widgets/dockwidget.h
        mainwindow/widgets/navigationbar.cpp
        mainwindow/widgets/navigationbar.h
        mainwindow/widgets/searchform.cpp
        mainwindow/widgets/searchform.h
        mainwindow/widgets/searchform.ui

        # subwindow
        subwindow/subwindow.cpp
        subwindow/subwindow.h
        subwindow/tabwidget.cpp
        subwindow/tabwidget.h

        # webengine
        webengine/filter.cpp
        webengine/filter.h
        webengine/urlinterceptor.cpp
        webengine/urlinterceptor.h
        webengine/webpage.cpp
        webengine/webpage.h
        webengine/webview.cpp
        webengine/webview.h

    # wallet (form autofill)
    wallet/wallet.cpp
    wallet/wallet.h

    # interfaces
    ${PROJECT_SOURCE_DIR}/include/plugininterface.h
    ${PROJECT_SOURCE_DIR}/include/profileinterface.h
    ${PROJECT_SOURCE_DIR}/include/browserinterface.h
)

if(CONFIG_QTBUG-62511)
    set_property(SOURCE ${PROJECT_SOURCE_DIR}/data/resources.qrc PROPERTY AUTORCC_OPTIONS "--format-version=1")
endif(CONFIG_QTBUG-62511)

# if you are using a custom build location for breakpad:
#if(CONFIG_USEBREAKPAD)
#    link_directories("${BREAKPAD_LIBRARY_DIRS}")
#endif(CONFIG_USEBREAKPAD)

if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
    add_executable(${CONFIG_POI_EXE} WIN32 ${srclist} ${PROJECT_SOURCE_DIR}/data/windows.rc)
else()
    add_executable(${CONFIG_POI_EXE} ${srclist})
endif()

target_include_directories(${CONFIG_POI_EXE}
    PRIVATE ${Boost_INCLUDE_DIRS}
    PRIVATE ${PROJECT_SOURCE_DIR}/include
    PRIVATE ${PROJECT_SOURCE_DIR}/lib
    PRIVATE ${PROJECT_SOURCE_DIR}/plugins
)

target_link_libraries(${CONFIG_POI_EXE}
        Qt5::Core Qt5::Widgets Qt5::WebEngineWidgets
        ${Boost_LIBRARIES}
        SingleApplication
        about
        addressbar
        configuration
        bookmarks downloads web urlfilter
)

if(CONFIG_USEBREAKPAD)
    target_link_libraries(${CONFIG_POI_EXE} Threads::Threads ${BREAKPAD_LIBRARIES})
    target_include_directories(${CONFIG_POI_EXE} PRIVATE ${BREAKPAD_INCLUDE_DIRS})
    target_compile_options(${CONFIG_POI_EXE} PRIVATE ${BREAKPAD_CFLAGS_OTHER})

    target_compile_definitions(${CONFIG_POI_EXE} PRIVATE BreakpadEnabled)
endif(CONFIG_USEBREAKPAD)

if(CONFIG_USEPLASMA)
    target_link_libraries(${CONFIG_POI_EXE} KF5::Wallet KF5::WindowSystem)
    target_compile_definitions(${CONFIG_POI_EXE} PRIVATE PLASMA)
endif(CONFIG_USEPLASMA)

target_compile_definitions(${CONFIG_POI_EXE}
    PRIVATE QAPPLICATION_CLASS=QApplication
    PRIVATE POI_NAME="${CONFIG_POI_NAME}"
    PRIVATE QTBUG_65223_WORKAROUND
    #PRIVATE QTBUG_68224_WORKAROUND
)

install(TARGETS ${CONFIG_POI_EXE} RUNTIME DESTINATION ${CONFIG_INSTALL_BIN} CONFIGURATIONS Release)