# Find includes in corresponding build directories
set(CMAKE_INCLUDE_CURRENT_DIR ON)

# Instruct CMake to run moc automatically when needed.
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)

set(poi_SRC
        # main
        main.cpp
        browser.cpp
        browser.h
        session.cpp
        session.h
        profilemanager.cpp
        profilemanager.h
        ../data/resources.qrc

        # main window
        mainwindow/mainwindow.cpp
        mainwindow/mainwindow.h
        mainwindow/mainwindow.ui
        mainwindow/widgets/dockwidget.cpp
        mainwindow/widgets/dockwidget.h
        mainwindow/widgets/navigationbar.cpp
        mainwindow/widgets/navigationbar.h
        mainwindow/widgets/searchform.cpp
        mainwindow/widgets/searchform.h
        mainwindow/widgets/searchform.ui

        # subwindow
        subwindow/subwindow.cpp
        subwindow/subwindow.h
        subwindow/tabwidget.cpp
        subwindow/tabwidget.h

        # webengine
        webengine/urlinterceptor.cpp
        webengine/urlinterceptor.h
        webengine/webpage.cpp
        webengine/webpage.h
        webengine/webview.cpp
        webengine/webview.h

        # plugin interfaces
        plugin.h
)

if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
    add_executable(${poi_NAME} WIN32 ${poi_SRC} ../data/windows.rc)
else()
    add_executable(${poi_NAME} ${poi_SRC})
endif()

target_include_directories(${poi_NAME}
        PRIVATE ${Boost_INCLUDE_DIRS}
        PRIVATE ../3rd-party
        PRIVATE ../lib ../plugins
        PRIVATE ../lib/configuration
        PRIVATE ../lib/web)

target_link_libraries(${poi_NAME}
        Qt5::Core Qt5::Widgets Qt5::Concurrent Qt5::WebEngineWidgets
        ${Boost_LIBRARIES}
        SingleApplication
        about
        addressbar
        configuration
        bookmarks downloads web
)

if(Plasma)
    target_link_libraries(${poi_NAME} KF5::WindowSystem)
    target_compile_definitions(${poi_NAME}
        PRIVATE PLASMA_BLUR     # give the main window a translucent background and blur
    )
endif(Plasma)

target_compile_definitions(${poi_NAME}
    PRIVATE QAPPLICATION_CLASS=QApplication
    PRIVATE QTBUG_65223_WORKAROUND
    #PRIVATE QTBUG_68224_WORKAROUND
)

install(TARGETS ${poi_NAME} RUNTIME DESTINATION ${BINARY_DESTINATION} CONFIGURATIONS Release)