linker.ld


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

ENTRY(_start)
OUTPUT_FORMAT(elf32-i386)

VADDR_BASE = 0xc0000000;

SECTIONS
{
    /*
     * First put the multiboot header, as it is required to be put very early
     * early in the image or the bootloader won't recognize the file format.
     */
    . = 0;
    .multiboot : {
        *(.multiboot.header)
    }

    /* Begin putting sections at 4 MiB */
    . = VADDR_BASE;

    .text ALIGN(4K) : AT(ADDR(.text) - VADDR_BASE + 4M) {
        begin_text = .;
        *(.multiboot.text)
        *(.text*)
        end_text = .;
    }
 
    /* Read-only data. */
    .rodata ALIGN(4K) : AT(ADDR(.rodata) - VADDR_BASE + 4M) {
        begin_rodata = .;
        *(.rodata*)
        end_rodata = .;
    }
 
    /* Read-write data (initialized) */
    .data ALIGN(4K) : AT(ADDR(.data) - VADDR_BASE + 4M) {
        begin_data = .;
        begin_constinit = .;
        *(.constinit)
        end_constinit = .;

        begin_ctors = .;
        KEEP(*(.init_array));   /* global constructors */
        end_ctors = .;

        *(.data)
        end_data = .;
    }
 
    /* Read-write data (uninitialized) and stack */
    .bss ALIGN(4K) : AT(ADDR(.bss) - VADDR_BASE + 4M) {
        begin_bss = .;
        *(.pages)
        *(.bss*)
        *(.stack)
        end_bss = .;
    }
}