PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Aqua-sama <aqua@iserlohn-fortress.net>

pkgname=breakpad-git
pkgdesc='An open-source multi-platform crash reporting system'

pkgver=0
pkgrel=1

url="https://chromium.googlesource.com/breakpad/breakpad"

arch=('x86_64')
license=('BSD-3clause')

depends=()
optdepends=()
makedepends=('git' 'make')
conflicts=('google-breakpad-svn' 'google-breakpad-git')
options=('staticlibs' '!strip')
source=("git+https://chromium.googlesource.com/breakpad/breakpad"
        "git+https://chromium.googlesource.com/linux-syscall-support")
sha512sums=('SKIP' 'SKIP')

prepare() {
    cd $srcdir/breakpad/src/third_party
    if [ ! -d lss/ ]; then
        mkdir lss
    fi
    cp $srcdir/linux-syscall-support/linux_syscall_support.h lss/linux_syscall_support.h
}

pkgver() {
    cd $srcdir/breakpad
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd breakpad
    ./configure --prefix=/usr
    make
}

package() {
    cd breakpad
    make DESTDIR="$pkgdir" install
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}