Initial upload of split zfs-utils 0.7.11

Split out into separate package as there's no need to make binary zfs
module packages depend on a dkms split package just to acquire the
utils.

1 files changed, 59 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..03b6879
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,59 @@
+# Maintainer: Eli Schwartz <eschwartz@archlinux.org>
+# Contributor: Iacopo Isimbaldi <isiachi@rhye.it>
+
+pkgname=zfs-utils
+pkgver=0.7.11
+pkgrel=1
+pkgdesc="Userspace utilities for the Zettabyte File System."
+arch=("i686" "x86_64")
+url="https://zfsonlinux.org/"
+license=('CDDL')
+makedepends=("git")
+source=("git+https://github.com/zfsonlinux/zfs.git#tag=zfs-${pkgver}?signed"
+        "zfs.initcpio.install"
+        "zfs.initcpio.hook")
+sha256sums=('SKIP'
+            'aa5706bf08b36209a318762680f3c9fb45b3fc4b8e4ef184c8a5370b2c3000ca'
+            'f95ad1a5421ccbb8b01f448373f46cfd1f718361a82c2687a597325cf9827e3e')
+validpgpkeys=('4F3BA9AB6D1F8D683DC2DFB56AD860EED4598027'  # Tony Hutter (GPG key for signing ZFS releases) <hutter2@llnl.gov>
+              'C33DF142657ED1F7C328A2960AB9E991C6AF658B') # Brian Behlendorf <behlendorf1@llnl.gov>
+
+prepare() {
+    cd "${srcdir}"/zfs
+
+    autoreconf -fi
+}
+
+build() {
+    cd "${srcdir}"/zfs
+
+    ./configure --prefix=/usr \
+                --sysconfdir=/etc \
+                --sbindir=/usr/bin \
+                --with-mounthelperdir=/usr/bin \
+                --libdir=/usr/lib \
+                --datadir=/usr/share \
+                --includedir=/usr/include \
+                --with-udevdir=/usr/lib/udev \
+                --libexecdir=/usr/lib/zfs \
+                --with-config=user
+    make
+}
+
+package() {
+    cd "${srcdir}"/zfs
+
+    make DESTDIR="${pkgdir}" install
+    install -D -m644 contrib/bash_completion.d/zfs "${pkgdir}"/usr/share/bash-completion/completions/zfs
+
+    # Remove uneeded files
+    rm -r "${pkgdir}"/etc/init.d
+    rm -r "${pkgdir}"/etc/sudoers.d #???
+    rm -r "${pkgdir}"/usr/lib/dracut
+    rm -r "${pkgdir}"/usr/lib/modules-load.d
+    rm -r "${pkgdir}"/usr/share/initramfs-tools
+    rm -r "${pkgdir}"/usr/share/zfs
+
+    install -D -m644 "${srcdir}"/zfs.initcpio.hook "${pkgdir}"/usr/lib/initcpio/hooks/zfs
+    install -D -m644 "${srcdir}"/zfs.initcpio.install "${pkgdir}"/usr/lib/initcpio/install/zfs
+}